Talk:Q309481

Queries

count number of obituaries

SELECT (COUNT(*) as ?ct)  WHERE { ?item wdt:P136 wd:Q309481 ; wdt:P31 wd:Q13442814 }

Try it!

SELECT (COUNT(*) as ?ct)  WHERE { ?item wdt:P136 wd:Q309481 }

Try it!

find more obituaries

SELECT DISTINCT ?item ?itemLabel ?title ("P??" as ?pr) ("Q309481" as ?value)
{
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "obituary haswbstatement:P31=Q13442814 -haswbstatement:P136=Q309481 -haswbstatement:P138=Q309481 -haswbstatement:P921=Q309481".
    ?title wikibase:apiOutput mwapi:title.
  }
  BIND(IRI(CONCAT(STR(wd:), ?title)) AS ?item)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
}

Try it!

One may want to differentiate:

• genre (P136) = obituary (Q309481) - a biographical text about a person. Use main subject (P921) to link to the item about the person
• main subject (P921) = obituary (Q309481) - a work about obituaries
• named after (P138) = obituary (Q309481) - something that is called "obituary", but isn't necessarily a biographical text about a person

find more obituaries ("in memoriam")

SELECT DISTINCT ?item ?itemLabel ?title ("P??" as ?pr) ("Q309481" as ?value)
{
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "memoriam haswbstatement:P31=Q13442814 -haswbstatement:P825 -haswbstatement:P136=Q309481 -haswbstatement:P138=Q309481 -haswbstatement:P921=Q309481".
    ?title wikibase:apiOutput mwapi:title.
  }
  BIND(IRI(CONCAT(STR(wd:), ?title)) AS ?item)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
}

Try it!

One may want to differentiate:

• obituaries
  • genre (P136) = obituary (Q309481) - a biographical text about a person
  • main subject (P921) = <name of a person> - obituary about this person
• dedication
  • dedicated to (P825) = <name of a person> - article about <some topic> dedicated to <name of a person>
  • main subject (P921) = <some topic>

articles about obituaries

• Items used: obituary (Q309481)   

• Properties used: main subject (P921)   

SELECT ?item ?itemLabel ?itemDescription
{
	?item wdt:P921 wd:Q309481 . 
	SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}

Try it!

Discussion

thanks Jura1 for tthese examples. i found this talk page by searching "search item by property value". given a known value as "4125622-0" i want to find the wd item having the GND ID (P227) property with this value. thanks for your help in advance! regards
no bias — קיין אומוויסנדיקע פּרעפֿערענצן — keyn umvisndike preferentsn ^{talk contribs} 13:17, 11 November 2019 (UTC)

p.s. the answer should of cause be (GND ID (P227) of deception (Q170028)).

p.p.s. there is no {{PQ|227|170028}}: GND ID (P227) of deception (Q170028), only template:QP